添加到桌面   加入收藏

批处置惩罚方式实现的目录比力工具

01-01 08:00 来源:未知 编辑:admin  人气:   点评:评论一下 刷新: 刷新文章
更新日志:
v4:
1.增添了盘算的进度显示;
2.找了新版的 md5sum.exe,没有对动态库的依赖。

工具一:md5comv4.bat 接受两个目录参数,盘算两个目录里每个文件的 md5 值,并给出报表文件 md5v4.txt,使用方法:
md5omv4.bat <目录1> <目录2>

凭据这 md5comv4.bat 天生的报表文件 md5v4.txt,可以找到两个目录中
1:同名而且 md5 相同的文件;
2:同名可是 md5 差别的文件;
3:差别名可是 md5 相同的文件;
4:统一目录中差别名可是 md5 相同的文件。

注重事项:
1:md5comv4.bat 不接受路径带有空格的目录名,可是可以接受带有空格的文件名;
2:md5 的盘算由 md5sum.exe 完成;
3:md5comv4.bat 运行时会发生大量暂时文件,这些文件由工具自动维护,不必手工清算。

这个工具都是下令行方式、文本界面的,对于习惯使用图形界面的朋侪来说,可能不利便,因此,不推荐习惯使用图形界面的朋侪使用。
复制代码 代码如下:


@echo off
setlocal enableextensions enabledelayedexpansion
rem 作者:rubble@126.com
rem 17:55 2009-4-14 版本:0.4
set dira=%~1
set dirb=%~2
if "%1" == "" (
echo 使用说明:请在下令行参数上指明两个目录,或在这里按提醒输入。
echo 下令行参数花样:批处置惩罚名 ^<目录1^> ^<目录2^>
echo.
set /p dira=请输入第一个目录的名字(可拖放并输入回车):
)
echo.
if "%2" == "" (
echo 使用说明:请在下令行参数上指明两个目录,或在这里按提醒输入。
echo 下令行参数花样:批处置惩罚名 ^<目录1^> ^<目录2^>
echo.
set /p dirb=请输入第二个目录的名字(可拖放并输入回车):
)

if "%dira%" == "" exit /b
if "%dirb%" == "" exit /b
for /F "delims=. tokens=1" %%A in ("%TIME%") do set startTime=%%A
for /F "delims=: tokens=1,2,3" %%A in ("%startTime%") do (
set startH=%%A
set startM=%%B
set startS=%%C
)

set TEMPDIR=TEMPMD5\
rd /Q /S %TEMPDIR% 1>NUL 2>NUL
md %TEMPDIR%
set mdfive=md5v4.txt
rem 已处置惩罚的文件数
set count=0
rem 文件夹 %dira% 和 %dirb% 里的文件总数
set total_count=0
rem 已处置惩罚的暂时文件数
set tmpf_count=0
rem 暂时文件总数,已知有 5 个了。其余的是 md5 值的个数
set tmpf_total_count=5
echo 第 1/2步,正在盘算,请稍候……
echo 正在比力 %dira% 和 %dirb% 中的文件的 md5 值 > %mdfive%
set list_fn_md=%TEMPDIR%list_fn_md
set list_fn_nmd=%TEMPDIR%list_fn_nmd
set list_fn_oa=%TEMPDIR%list_fn_oa
set list_fn_ob=%TEMPDIR%list_fn_ob
set list_all_md=%TEMPDIR%list_all_md

call :COUNTFILES %dira%
call :COUNTFILES %dirb%

for /f "delims=" %%a in ('dir /b /a:-d "%dira%\*"') do (
set fn=%%~nxa
for /f "tokens=1 delims= " %%A in ('md5sum "%dira%\%%a"') do set mda=%%A
set /a count=!count!+1
call :PROGRESS !count! !total_count!
if "!mda:~0,1!" == "\" set mda=!mda:~1,1024!
rem 以 !mda! 为文件名,记载 md5 为 !mda! 的文件
call :ADDMDFN "%TEMPDIR%!mda!" "%dira%\!fn!"
rem 把 md5 值记载到文件里,保证不重复
call :ADDMDLIST !mda!
if exist "%dirb%\!fn!" (
for /f "tokens=1 delims= " %%A in ('md5sum "%dirb%\!fn!"') do set mdb=%%A
set /a count=!count!+1
call :ADDMDFN "%TEMPDIR%!mdb!" "%dirb%\!fn!"
call :PROGRESS !count! !total_count!
if "!mdb:~0,1!" == "\" set mdb=!mdb:~1,1024!
if "!mda!" == "!mdb!" (
rem 记载文件名相同而且 md5 相同的文件
echo !mda! !mdb! !fn! >> "!list_fn_md!"
) else (
rem 记载文件名相同但 md5 不相同的文件
echo !mda! !mdb! !fn! >> "!list_fn_nmd!"
call :ADDMDLIST !mdb!
)
) else (
rem 记载只在 %dira% 中泛起的文件
echo !mda! !fn! >> "!list_fn_oa!"
)
)
for /f "delims=" %%a in ('dir /b /a:-d "%dirb%\*"') do (
set fn=%%~nxa
if not exist "%dira%\!fn!" (
for /f "tokens=1 delims= " %%A in ('md5sum "%dirb%\%%a"') do set mdb=%%A
if "!mdb:~0,1!" == "\" set mdb=!mdb:~1,1024!
rem 记载只在 %dirb% 中泛起的文件
echo !mdb! !fn! >> "!list_fn_ob!"
rem 把 md5 值记载到文件里,保证不重复
call :ADDMDLIST !mdb!
call :ADDMDFN "%TEMPDIR%!mdb!" "%dirb%\!fn!"
set /a count=!count!+1
call :PROGRESS !count! !total_count!
)
)
echo 第 2/2步,正在统计,请稍候……
echo 统计:>>%mdfive%
echo 左:%dira% >> %mdfive%
echo 右:%dirb% >> %mdfive%
if not exist "%list_fn_md%" set /a tmpf_total_count-=1
if not exist "%list_fn_nmd%" set /a tmpf_total_count-=1
if not exist "%list_fn_oa%" set /a tmpf_total_count-=1
if not exist "%list_fn_ob%" set /a tmpf_total_count-=1
if not exist "%list_all_md%" set /a tmpf_total_count-=1
echo 两个目录中都存在且 md5 相同的文件:>> %mdfive%
call :OUTPUTLIST "%list_fn_md%"
echo ===============================================================================================>> %mdfive%
echo 左:%dira% >> %mdfive%
echo 右:%dirb% >> %mdfive%
echo 两个目录中都存在但 md5 不相同的文件:>> %mdfive%
call :OUTPUTLIST "%list_fn_nmd%"
echo ===============================================================================================>> %mdfive%
echo 只在目录 %dira% 中存在的文件:>> %mdfive%
call :OUTPUTLIST "%list_fn_oa%"
echo ===============================================================================================>> %mdfive%
echo 只在目录 %dirb% 中存在的文件:>> %mdfive%
call :OUTPUTLIST "%list_fn_ob%"
echo ===============================================================================================>> %mdfive%
echo 以 md5 汇总的文件列表:>> %mdfive%
call :OUTPUTLIST_MD "%list_all_md%"

goto ALLDONE

rem 统计文件夹里的文件数目,放到全局变量 total_count 里
:COUNTFILES
if %1=="" goto :EOF
for /f %%a in ('dir /b /a:-d "%~1\*"') do (
set /a total_count=!total_count!+1
)
goto :EOF

rem 参数 %1 必须加双引号
:OUTPUTLIST
if %1 == "" goto :EOF
if not exist %1 goto :EOF
set tcnt=0
for /f "tokens=1* delims= " %%a in (%~1) do (
echo %%a %%b >> %mdfive%
set /a tcnt+=1
)
echo !tcnt! >> %mdfive%
set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!
goto :EOF

rem 参数 %1 必须加双引号
:OUTPUTLIST_MD
if %1 == "" goto :EOF
if not exist %1 goto :EOF

set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!

set md_count=0
for /f "tokens=1* delims= " %%a in (%~1) do (
echo %%a >> %mdfive%
set tcnt=0
for /f "tokens=1* delims= " %%A in (!TEMPDIR!%%a) do (
echo %%A %%B >> %mdfive%
set /a tcnt+=1
)
set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!
echo !tcnt! >> %mdfive%
set /a md_count+=1
echo. >> %mdfive%
)
echo %md_count% >> %mdfive%
goto :EOF

rem 函数:把 md5 值生存到一个名为 !list_all_md! 的文件里,
rem 并保证不生存重复的 md5 值
:ADDMDLIST
if %1 == "" goto :EOF
if exist "!list_all_md!" (
rem 这里的 delims 要么删除,要么做成像下面这行的样子,在等号后面加个空格
rem for /f "tokens=1 delims= " %%a in (!list_all_md!) do (
for /f "tokens=1 " %%a in (!list_all_md!) do (
if "%%a" == "%1" goto :EOF
)
)
echo %1 >> "!list_all_md!"
rem 记载暂时文件总数
set /a tmpf_total_count+=1
goto :EOF

rem 函数:以 %1 为文件名,生存 %2
rem %1:在这个应用里是 md5 值
rem %2:md5 值为 %1 的文件
:ADDMDFN
if %1 == "" goto :EOF
if %2 == "" goto :EOF
echo %2 >> %1
goto :EOF

:PROGRESS
set tips=
set backspace=
set /a percent=%1*100/%2
set /a char=%1%%7
set /a bnum=%percent%/10
set /a snum=10-%bnum%
for /L %%a in (1, 1, %bnum%) do set /p=▌<NUL
for /L %%a in (1, 1, %snum%) do set /p= <NUL
set /p=%1/%2 %percent%%% <NUL
set /p=!tips:~%char%,1!<NUL
if "%percent%" == "100" (
echo.
goto :EOF
)
set /p=%backspace%<NUL
goto :EOF

rem :PROGRESS
rem set tips=
rem set backspace=
rem set /a char=%1%%7
rem set /p=!tips:~%char%,1!<NUL
rem set /p=%backspace%<NUL
rem goto :EOF

:ALLDONE

rd /Q /S %TEMPDIR% 1>NUL 2>NUL
for /F "delims=. tokens=1" %%A in ("%TIME%") do set endTime=%%A
for /F "delims=: tokens=1,2,3" %%A in ("%endTime%") do (
set endH=%%A
set endM=%%B
set endS=%%C
)
if "%endM:~0,1%" == "0" set endM=%endM:~1,1%
if "%endS:~0,1%"=="0" set endS=%endS:~1,1%
for /F "delims=: tokens=1,2,3" %%A in ("%startTime%") do (
set startH=%%A
set startM=%%B
set startS=%%C
)
if "%startM:~0,1%"=="0" set startM=%startM:~1,1%
if "%startS:~0,1%"=="0" set startS=%startS:~1,1%
set /A totalTime=%endH%*3600+%endM%*60+%endS%-(%startH%*3600+%startM%*60+%startS%)
echo 共用时 %totalTime% 秒。
echo 起始时间:%startH%:%startM%:%startS%>>%mdfive%
echo 竣事时间:%endH%:%endM%:%endS%>>%mdfive%
echo 共用时 %totalTime% 秒。>>%mdfive%
start %mdfive%
echo 
endlocal
@echo on


文件打包下载
[提醒] 转载请保留( 飞猪云教程)文章链接,谢谢!对本文有疑问欢迎留言讨论 ( 我有话说)!
元芳,把你的犀利的看法写到这里可好?
  • 全部评论(0
    还没有评论,快来抢沙发吧!